ID |
NameU |
Category |
Description |
RuleTarget |
RuleFilter |
RuleTest |
1 |
UngluedConnector |
Connectivity |
Connector is not glued at both ends. |
|
ROLE()=1 |
AND(AGGCOUNT(GLUEDSHAPES(4)) = 1, AGGCOUNT(GLUEDSHAPES(5)) = 1) |
2 |
StartWithoutTerminator |
Start / End |
Flowchart shape has no incoming connectors and is not a Start/End shape. |
|
AND(OR(HASCATEGORY("Flowchart"),ONLAYER("Flowchart")),NOT(OR(HASCATEGORY("Start/End"),STRSAME(LEFT(MASTERNAME(750),9),"Start/End"),STRSAME(LEFT(MASTERNAME(750),10),"Terminator")))) |
AGGCOUNT(GLUEDSHAPES(1)) > 0 |
3 |
EndWithoutTerminator |
Start / End |
Flowchart shape has no outgoing connectors and is not a Start/End shape. |
|
AND(OR(HASCATEGORY("Flowchart"),ONLAYER("Flowchart")),NOT(OR(HASCATEGORY("Start/End"),STRSAME(LEFT(MASTERNAME(750),9),"Start/End"),STRSAME(LEFT(MASTERNAME(750),10),"Terminator")))) |
AGGCOUNT(GLUEDSHAPES(2)) > 0 |
4 |
NoStartTerminator |
Start / End |
Flowchart does not start with a Start/End shape. |
|
AGGCOUNT(FILTERSET(SHAPESONPAGE(), "OR(HASCATEGORY(""Flowchart""),ONLAYER(""Flowchart""))")) > 0 |
AGGCOUNT(FILTERSET(SHAPESONPAGE(), "AND(OR(HASCATEGORY(""Start/End""),STRSAME(LEFT(MASTERNAME(750),9),""Start/End""),STRSAME(LEFT(MASTERNAME(750),10),""Terminator"")),AGGCOUNT(CONNECTEDSHAPES(2))>0)")) > 0 |
5 |
NoEndTerminator |
Start / End |
Flowchart does not end with a Start/End shape. |
|
AGGCOUNT(FILTERSET(SHAPESONPAGE(), "OR(HASCATEGORY(""Flowchart""),ONLAYER(""Flowchart""))")) > 0 |
AGGCOUNT(FILTERSET(SHAPESONPAGE(), "AND(OR(HASCATEGORY(""Start/End""),STRSAME(LEFT(MASTERNAME(750),9),""Start/End""),STRSAME(LEFT(MASTERNAME(750),10),""Terminator"")),AGGCOUNT(CONNECTEDSHAPES(1))>0)")) > 0 |
6 |
UnconnectedShape |
Connectivity |
Flowchart shape is not connected to any other shape. |
|
OR(HASCATEGORY("Flowchart"),ONLAYER("Flowchart")) |
AGGCOUNT(CONNECTEDSHAPES(0)) > 0 |
7 |
TerminatorInMiddle |
Connectivity |
Start/End shape has both incoming and outgoing connectors. |
|
OR(HASCATEGORY("Start/End"),STRSAME(LEFT(MASTERNAME(750),9),"Start/End"),STRSAME(LEFT(MASTERNAME(750),10),"Terminator")) |
NOT(AND(AGGCOUNT(CONNECTEDSHAPES(1))>0,AGGCOUNT(CONNECTEDSHAPES(2))>0)) |
8 |
TooFewOutConns |
Connectivity |
Decision shape should have more than one outgoing connector. |
|
OR(HASCATEGORY("Decision"),STRSAME(LEFT(MASTERNAME(750),8),"Decision")) |
AGGCOUNT(GLUEDSHAPES(2)) > 1 |
9 |
NonFlowchartShape |
Connectivity |
Connected shape is not recognized as a Flowchart shape. |
|
NOT(OR(HASCATEGORY("Flowchart"),ONLAYER("Flowchart"))) |
AGGCOUNT(GLUEDSHAPES(0)) = 0 |
10 |
NoShapeText |
Text |
Flowchart shape has no text label. |
|
OR(HASCATEGORY("Flowchart"),ONLAYER("Flowchart")) |
NOT(STRSAME(SHAPETEXT(TheText), "")) |
11 |
OutsideCFF |
Cross - Functional |
Flowchart shapes should belong to a Swimlane. |
|
AGGCOUNT(FILTERSET(SHAPESONPAGE(),"HASCATEGORY(""Swimlane"")"))>0 |
AGGCOUNT(FILTERSET(SHAPESONPAGE(),"AND(OR(HASCATEGORY(""Flowchart""),ONLAYER(""Flowchart"")),AGGCOUNT(FILTERSET(PARENTCONTAINERS(),""HASCATEGORY(""""Swimlane"""")""))=0)"))=0 |